#include "colors.inc"
#include "textures.inc"
#include "woods.inc"
#include "metals.inc"
#include "finish.inc"
#include "stones.inc"

camera {
  location < 10, 6, -10 >
  look_at  < 0, 7, 0  >
}

/*
An example of a more complex scene. The ceiling fan is constructed from
a thin box rotated a few degrees about an axis, added some brass and
the light source.

This scene was created by Kwan L. Lowe for the FLUX presentation.
*/
plane { <0, 1, 0> 13 pigment { White } inverse }
plane { x, -8 pigment { White rotate 90*x}}
plane { z, 10 pigment { Gray  rotate 90*z} inverse }
plane { 
  y, 0 
  finish { Glossy }
  pigment { checker color Black, color White }
}


#declare ceiling_fan=union{
    
    #declare light_assembly=union {
      sphere {
        < 0, 1, 0 >, .5
        // texture { Yellow_Glass } 
	pigment { Yellow transmit .45 }
        finish { Luminous } 
      }
      
      light_source {
        < 0, 1, 0 > color White 
	// area_light < 1.5, 0, 0 > < 0, 0 , 1.5 > 5,5
	adaptive 1
      }
    }

    object { light_assembly }
    
    cylinder {
      <0, 1.6, 0 >
      <0, 2.1, 0 >, .3
      texture { Tinny_Brass }
    }
   
    #declare blades=union {
      #declare blade=union{
        box {
          < 4, -0.05, -.4 >
          < .5, 0.05, .4 >
          pigment { P_WoodGrain3B rotate 90*y}
          rotate 5*x
          translate < 0, 1.8, 0 > 
        }
	box {
	  < .7, -0.051, -.2 >
	  < .2, 0.05, .2 >
	  texture { Tinny_Brass }
	  rotate 5*x
	  translate < 0, 1.8, 0 >
	}
      }

      object { blade }
      object { blade rotate 90*y }
      object { blade rotate 180*y }
      object { blade rotate 270*y }
    }

    object { blades rotate 7200*clock*y }
}

#declare globe_painting= box {
    < 4, 0, 0>
    < 0, 4, -.1>
    pigment {
      image_map {
      gif "earth.gif" 
      map_type 3
    }
    scale 4
  }
}

#declare henge_painting= box {
    < 4, 0, 0>
    < 0, 4, -.1>
    pigment {
      image_map {
      gif "tree.gif" 
      map_type 3
    }
    scale 4
  }
}

#declare wall_mirror = 
  box {
    < 4, 0, 0>
    < 0, 4, -.1>
    texture { Mirror }
  }

#declare table=union {

  #declare leg=union {
    cone {
      <0, .2, 0>, .1
      <0, 4, 0>, .2
      pigment { P_WoodGrain3B }
    }
    cone {
      <0, 0, 0>, .1
      <0, .2, 0>, .11
      pigment { P_Gold3 }
    }
  
    sphere {
      <0, 4, 0>, .12
      pigment { P_WoodGrain3B }
    }
    
    sphere {
      <0, 1, 0>, .15
      pigment { P_WoodGrain3B }
    }
  }
  
  object { leg }
  object { leg translate < 4, 0, 0 > }
  object { leg translate < 0, 0, 2 > }
  object { leg translate < 4, 0, 2 > }
  
  box {
    < 4.5, 4.1, 0 >
    < -0.5, 4.7, 2 >
    pigment { P_WoodGrain3B }
  }
}

#declare shiny_ball=
  sphere {
    <0, 0, 0>, 1
    texture { Tinny_Brass } 
  }

  
object { ceiling_fan translate <0, 10, 0>}
object { globe_painting translate < -2.0, 6, 9.9 > } 
object { henge_painting rotate 90*y translate < -7.6, 6, 2> }
object { wall_mirror rotate 90*y translate < -7.6, 6, 8> }
object { table translate <-2, -.2, 8 > }
object { table rotate y*90 translate <-7, -.2, 3 > }
// object { shiny_ball translate < -4, 4, 2 > }